MainForm.vb

Imports System.IO
Imports Microsoft.VisualBasic.ControlChars
Imports Microsoft.Win32
Imports SysprepPreparator.Classes
Imports SysprepPreparator.Helpers
Imports System.Text.Encoding

Public Class MainForm

    ''' <summary>
    ''' The current page in the wizard
    ''' </summary>
    ''' <remarks></remarks>
    Dim CurrentWizardPage As New WizardPage()
    ''' <summary>
    ''' The pages in which the verification system should run checks
    ''' </summary>
    ''' <remarks></remarks>
    Dim VerifyInPages As New List(Of WizardPage.Page) From {
        WizardPage.Page.SysCheckPage
    }
    ''' <summary>
    ''' Determines whether the CCPs have been run to avoid running them again
    ''' </summary>
    ''' <remarks></remarks>
    Dim IsComputerChecked As Boolean = False

    ''' <summary>
    ''' The list of all the performed CCPs
    ''' </summary>
    ''' <remarks></remarks>
    Dim PerformedChecks As New List(Of CompatibilityCheckerProviderStatus)

    ''' <summary>
    ''' The current Sysprep configuration
    ''' </summary>
    ''' <remarks></remarks>
    Dim SysprepConfiguration As New SysprepConfig()

    ''' <summary>
    ''' This event is raised when a Preparation Task is about to start
    ''' </summary>
    ''' <param name="taskName">The name of the task</param>
    ''' <remarks></remarks>
    Public Event TaskStarted(taskName As String)

    ''' <summary>
    ''' This event is raised when a Preparation Task has finished and reporting will occur
    ''' </summary>
    ''' <remarks></remarks>
    Public Event TaskReported(Task As Dictionary(Of String, PreparationTasks.PreparationTask.PreparationTaskStatus), progressPercentage As Double)

    ''' <summary>
    ''' This event is raised when a Preparation Task updates a subprocess status
    ''' </summary>
    ''' <param name="Status">The reported status</param>
    ''' <remarks></remarks>
    Public Event SubProcessStatusUpdated(Status As String)

    Public Event CheckFinished(Check As CompatibilityCheckerProviderStatus)

    Private Const CodeName As String = "baryl"

    Private TaskNames As New List(Of String)

    ''' <summary>
    ''' Handles the TaskStarted event
    ''' </summary>
    ''' <param name="taskName">The name of the task</param>
    ''' <remarks></remarks>
    Private Sub OnTaskStarted(taskName As String) Handles Me.TaskStarted
        Dim ControlIndex As Integer = TaskNames.FindIndex(Function(tn) tn = taskName)
        If ControlIndex > -1 Then flpTasks.Controls.Cast(Of PTActivityReporterControl)()(ControlIndex).SetActive()
    End Sub

    ''' <summary>
    ''' Handles the TaskReported event
    ''' </summary>
    ''' <param name="Task">The reported item featuring the task name and whether the PT succeeded</param>
    ''' <param name="progressPercentage">The percentage to report to progress bars</param>
    ''' <remarks></remarks>
    Private Sub OnTaskReported(Task As Dictionary(Of String, PreparationTasks.PreparationTask.PreparationTaskStatus), progressPercentage As Double) Handles Me.TaskReported
        Dim taskName As String = Task.Keys(0)
        Dim translatedTaskStatus As String = ""

        Dim ControlIndex As Integer = TaskNames.FindIndex(Function(tn) tn = taskName)
        If ControlIndex > -1 Then
            flpTasks.Controls.Cast(Of PTActivityReporterControl)()(ControlIndex).SetInactive()
            flpTasks.Controls.Cast(Of PTActivityReporterControl)()(ControlIndex).TaskStatus = Task(taskName)
        End If
    End Sub

    ''' <summary>
    ''' Handles the SubProcessStatusUpdated event
    ''' </summary>
    ''' <param name="Status">The reported status</param>
    Private Sub OnSubProcessStatusUpdated(Status As String) Handles Me.SubProcessStatusUpdated
        SettingPreparationPage_SubProcessProgressLabel.Text = Status
    End Sub

    Private Sub OnCheckFinished(Check As CompatibilityCheckerProviderStatus) Handles Me.CheckFinished
        PerformedChecks.Add(Check)
        SysCheckPage_ChecksLv.Items.Add(New ListViewItem(New String() {Check.StatusMessage.StatusTitle, If(Check.Compatible, GetValueFromLanguageData("Common.Common_Yes"), GetValueFromLanguageData("Common.Common_No")), Check.StatusMessage.SeverityToString(Check.StatusMessage.StatusSeverity)}))
    End Sub

    ''' <summary>
    ''' A public method for the PT Helper to report task starts
    ''' </summary>
    ''' <param name="taskName">The name of the task</param>
    ''' <remarks></remarks>
    Sub ReportTaskStart(taskName As String)
        RaiseEvent TaskStarted(taskName)
    End Sub

    ''' <summary>
    ''' A public method for the PT Helper to report task status
    ''' </summary>
    ''' <param name="task">The reported item featuring the task name and whether the PT succeeded</param>
    ''' <param name="progressPercentage">The percentage to report to progress bars</param>
    ''' <remarks></remarks>
    Sub ReportTaskSuccess(task As Dictionary(Of String, PreparationTasks.PreparationTask.PreparationTaskStatus), progressPercentage As Double)
        RaiseEvent TaskReported(task, progressPercentage)
    End Sub

    ''' <summary>
    ''' A public method for the PT Helper to report task subprocess status updates
    ''' </summary>
    ''' <param name="Status">The reported status</param>
    ''' <remarks></remarks>
    Sub ReportSubProcessStatusUpdate(Status As String)
        RaiseEvent SubProcessStatusUpdated(Status)
    End Sub

    Sub ReportCheckFinished(Check As CompatibilityCheckerProviderStatus)
        RaiseEvent CheckFinished(Check)
    End Sub

    Dim OriginalWindowBounds As Rectangle           ' Window bounds before full-screen
    Dim OriginalWindowState As FormWindowState      ' Window state before full-screen

    Dim currentTheme As Theme

    Async Sub RunAutoMode()
        DynaLog.LogMessage("Auto Mode enabled -- performing steps automatically...")
        WindowHelper.DisableCloseCapability(Handle)

        Do Until SettingPreparationPanel.Visible
            If SystemCheckPanel.Visible AndAlso Not Environment.GetCommandLineArgs().Contains("/test") Then
                Await Task.Run(Function()
                                   While Not IsComputerChecked
                                       System.Threading.Thread.Sleep(50)
                                   End While
                                   Return True
                               End Function)

                If PerformedChecks.Any(Function(check) Not check.Compatible) Then
                    Exit Do
                End If

                ' Checks we have reported warnings on may be important to read
                If PerformedChecks.Any(Function(check) check.StatusMessage.StatusSeverity = StatusMessage.StatusMessageSeverity.Warning) Then
                    Dim compatWarningStr As String = ""

                    For Each compatWarning In PerformedChecks.Where(Function(check) check.StatusMessage.StatusSeverity = StatusMessage.StatusMessageSeverity.Warning)
                        compatWarningStr &= String.Format("- {0}: {1}{2}", compatWarning.StatusMessage.StatusTitle, compatWarning.StatusMessage.StatusDescription, Environment.NewLine)
                    Next

                    If MessageBox.Show(Me, String.Format(GetValueFromLanguageData("MainForm.AutoMode_WarningsDetected"), compatWarningStr),
                                       Text, MessageBoxButtons.YesNo, MessageBoxIcon.Exclamation) = DialogResult.No Then
                        Exit Do
                    End If
                End If
            End If

            Next_Button.PerformClick()
            Await Task.Delay(100)
        Loop
    End Sub

    ''' <summary>
    ''' Changes the wizard page
    ''' </summary>
    ''' <param name="NewPage">The new page to change to</param>
    ''' <remarks>Verification in a page may be done</remarks>
    Sub ChangePage(NewPage As WizardPage.Page)
        DynaLog.LogMessage("Changing current page of the wizard...")
        DynaLog.LogMessage("New page to load: " & NewPage.ToString())
        If NewPage > CurrentWizardPage.WizardPage AndAlso VerifyInPages.Contains(CurrentWizardPage.WizardPage) Then
            If Not VerifyOptionsInPage(CurrentWizardPage.WizardPage) Then Exit Sub
        End If

        WelcomePage.Visible = (NewPage = WizardPage.Page.WelcomePage)
        SystemCheckPanel.Visible = (NewPage = WizardPage.Page.SysCheckPage)
        AdvSettingsPanel.Visible = (NewPage = WizardPage.Page.AdvSettingsPage)
        SettingPreparationPanel.Visible = (NewPage = WizardPage.Page.SettingPreparationPage)
        FinishPanel.Visible = (NewPage = WizardPage.Page.FinishPage)

        CurrentWizardPage.WizardPage = NewPage

        Select Case NewPage
            Case WizardPage.Page.SysCheckPage
                CheckComputer()
        End Select

        Next_Button.Enabled = (Not NewPage <> WizardPage.Page.FinishPage) OrElse (Not NewPage + 1 >= WizardPage.PageCount)
        Cancel_Button.Enabled = Not (NewPage = WizardPage.Page.FinishPage)
        Back_Button.Enabled = Not (NewPage = WizardPage.Page.WelcomePage) And Not (NewPage = WizardPage.Page.FinishPage)

        Next_Button.Text = If(NewPage = WizardPage.Page.FinishPage, GetValueFromLanguageData("Common.Common_Close"), GetValueFromLanguageData("Common.Common_Next"))

        ButtonPanel.Visible = Not (NewPage > WizardPage.Page.AdvSettingsPage)

        If NewPage = WizardPage.Page.SettingPreparationPage Then
            WindowHelper.DisableCloseCapability(Handle)
            PrepareComputer()
        ElseIf NewPage = WizardPage.Page.FinishPage Then
            SysprepComputer()
        End If
    End Sub

    Sub ChangeTheme()
        ThemeHelper.LoadThemes()

        Dim ColorModeRk As RegistryKey = Registry.CurrentUser.OpenSubKey("SOFTWARE\Microsoft\Windows\CurrentVersion\Themes\Personalize", False)
        Dim ColorModeVal As Integer = ColorModeRk.GetValue("AppsUseLightTheme", 1)
        ColorModeRk.Close()

        currentTheme = ThemeHelper.GetThemes().FirstOrDefault(Function(Theme) Theme.IsDark = (ColorModeVal = 0))

        If currentTheme IsNot Nothing Then
            BackColor = currentTheme.BackgroundColor
            ForeColor = currentTheme.ForegroundColor
            PageContainerPanel.BackColor = currentTheme.SectionBackgroundColor
            ButtonPanel.BackColor = currentTheme.BackgroundColor
            SysCheckPage_CheckDetailsGB.ForeColor = currentTheme.ForegroundColor
            SysCheckPage_ChecksLv.BackColor = currentTheme.SectionBackgroundColor
            SysCheckPage_ChecksLv.ForeColor = currentTheme.ForegroundColor
            SysCheckPage_CheckDetails_ResolutionValue.BackColor = currentTheme.SectionBackgroundColor
            SysCheckPage_CheckDetails_ResolutionValue.ForeColor = currentTheme.ForegroundColor
            AdvSettingsPage_CleanupActionCBox.BackColor = currentTheme.SectionBackgroundColor
            AdvSettingsPage_CleanupActionCBox.ForeColor = currentTheme.ForegroundColor
            AdvSettingsPage_ShutdownOptionsCBox.BackColor = currentTheme.SectionBackgroundColor
            AdvSettingsPage_ShutdownOptionsCBox.ForeColor = currentTheme.ForegroundColor
            AdvSettingsPage_SysprepUnatt_AnswerFileText.BackColor = currentTheme.SectionBackgroundColor
            AdvSettingsPage_SysprepUnatt_AnswerFileText.ForeColor = currentTheme.ForegroundColor

            OnlineAppxRemovalDialog.BackColor = currentTheme.SectionBackgroundColor
            OnlineAppxRemovalDialog.ForeColor = currentTheme.ForegroundColor
            OnlineAppxRemovalDialog.ListView1.BackColor = currentTheme.SectionBackgroundColor
            OnlineAppxRemovalDialog.ListView1.ForeColor = currentTheme.ForegroundColor

            ThemeHelper.CurrentTheme = currentTheme
        End If
    End Sub

    Sub ChangeLanguage(LanguageCode As String)
        If Not File.Exists(Path.Combine(Application.StartupPath, "Languages", "lang_" & LanguageCode & ".ini")) Then
            LanguageCode = "en"
        End If
        LoadLanguageFile(Path.Combine(Application.StartupPath, "Languages", "lang_" & LanguageCode & ".ini"))

        AboutBtn.Text = GetValueFromLanguageData("Common.Common_About")
        Back_Button.Text = GetValueFromLanguageData("Common.Common_Back")
        Next_Button.Text = GetValueFromLanguageData("Common.Common_Next")
        Cancel_Button.Text = GetValueFromLanguageData("Common.Common_Cancel")
        WelcomePage_Header.Text = GetValueFromLanguageData("MainForm.WelcomePanel_Header")
        WelcomePage_Description.Text = GetValueFromLanguageData("MainForm.WelcomePanel_Description")
        SysCheckPage_Header.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_Header")
        SysCheckPage_Description.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_Description")
        SysCheckPage_CheckCH.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CheckField")
        SysCheckPage_CompatibleCH.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CompatibleField")
        SysCheckPage_SeverityCH.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_SeverityField")
        SysCheckPage_CheckDetailsGB.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CheckDetailsField")
        SysCheckPage_CheckDetails_Description.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CheckDescField")
        SysCheckPage_CheckDetails_Resolution.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CheckResField")
        SysCheckPage_CheckAgainBtn.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_CheckAgainBtn")
        SysCheckPage_ProgressLabel.Text = GetValueFromLanguageData("Common.Common_PleaseWait")
        SysCheckPage_RemoveAppxBtn.Text = GetValueFromLanguageData("MainForm.SystemChecksPanel_StoreAppRemovalBtn")
        AdvSettingsPage_Header.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_Header")
        AdvSettingsPage_Description.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_Description")
        AdvSettingsPage_ConfigSysprepSettings.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_ConfigCheck")
        AdvSettingsPage_CleanupActionLabel.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_CleanupActionField")
        AdvSettingsPage_CleanupActionCBox.Items.AddRange(New String() {GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_EnterOOBE_CA"), GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_EnterAudit_CA")})
        AdvSettingsPage_ShutdownOptionLabel.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_ShutdownOptionField")
        AdvSettingsPage_ShutdownOptionsCBox.Items.AddRange(New String() {GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_RebootSO"), GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_ShutdownSO"), GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_QuitSO")})
        AdvSettingsPage_CleanupAction_Generalize.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_GeneralizeField")
        AdvSettingsPage_SysprepUnattLabel.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_AnswerFileField")
        AdvSettingsPage_SysprepUnatt_Btn.Text = GetValueFromLanguageData("Common.Common_Browse")
        AdvSettingsPage_VMMode.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_VMModeField")
        AdvSettingsPage_VMModeExplanationLink.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_VMModeLink")
        AdvSettingsPage_CopyProfile.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_CopyProfileField")
        AdvSettingsPage_SysprepPrepToolDeploySteps.Text = GetValueFromLanguageData("MainForm.AdvancedSettingsPanel_ExplanationField")
        SettingPreparationPage_Header.Text = GetValueFromLanguageData("MainForm.PreparationPanel_Header")
        SettingPreparationPage_Description.Text = GetValueFromLanguageData("MainForm.PreparationPanel_Description")
        FinishPage_Header.Text = GetValueFromLanguageData("MainForm.FinishPanel_Header")
        FinishPage_Description.Text = GetValueFromLanguageData("MainForm.FinishPanel_Description")
        FinishPage_CloseBtn.Text = GetValueFromLanguageData("MainForm.FinishPanel_CloseBtn")
        FinishPage_ResysprepBtn.Text = GetValueFromLanguageData("MainForm.FinishPanel_RelaunchBtn")
        FinishPage_RestartBtn.Text = GetValueFromLanguageData("MainForm.FinishPanel_RestartBtn")
    End Sub

    ''' <summary>
    ''' Verifies user-specified settings in the specified wizard page
    ''' </summary>
    ''' <param name="WizardPage">The wizard page to check on</param>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Function VerifyOptionsInPage(WizardPage As WizardPage.Page) As Boolean
        DynaLog.LogMessage("Verifying user options before moving on to next page...")
        DynaLog.LogMessage("Page in which we need to verify user settings: " & WizardPage.ToString())
        Select Case WizardPage
            Case SysprepPreparator.WizardPage.Page.SysCheckPage
                If Not Environment.GetCommandLineArgs().Contains("/test") AndAlso PerformedChecks.Any(Function(PerformedCheck) PerformedCheck.Compatible = False) Then
                    MessageBox.Show(GetValueFromLanguageData("MainForm.IncompatibleCCPMessage"), Text, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
                    Return False
                End If
        End Select
        Return True
    End Function

    ''' <summary>
    ''' Starts the CCP Helper and reports the events logged by each of the CCPs
    ''' </summary>
    ''' <remarks></remarks>
    Private Async Sub CheckComputer()
        If IsComputerChecked Then Exit Sub

        SysCheckPage_ChecksLv.Items.Clear()
        Refresh()
        SysCheckPage_CheckAgainBtn.Enabled = False
        TableLayoutPanel1.Enabled = False
        SysCheckPage_CCPProgressBar.Style = ProgressBarStyle.Marquee
        SysCheckPage_CCPProgressBar.Value = 0
        SysCheckPage_CCPProgressPanel.Visible = True
        SysCheckPage_CheckDetailsTLP.Visible = False
        Cursor = Cursors.WaitCursor
        PerformedChecks = Await Task.Run(Function()
                                             Return CompatibilityCheckerHelper.RunChecks(CheckFinishedReporter:=Sub(Check As CompatibilityCheckerProviderStatus)
                                                                                                                    ReportCheckFinished(Check)
                                                                                                                End Sub)
                                         End Function)
        Cursor = Cursors.Arrow
        SysCheckPage_CheckAgainBtn.Enabled = True
        TableLayoutPanel1.Enabled = True
        SysCheckPage_CCPProgressPanel.Visible = False
        SysCheckPage_CCPProgressBar.Style = ProgressBarStyle.Blocks
        SysCheckPage_CCPProgressBar.Value = 100
        IsComputerChecked = True
    End Sub

    ''' <summary>
    ''' Starts the PT Helper
    ''' </summary>
    ''' <remarks></remarks>
    Private Async Sub PrepareComputer()
        Refresh()
        ' Get PT names so we can pre-populate the new controls
        TaskNames = PreparationTaskHelper.GetPreparationTaskNames()
        Dim PTControls As New List(Of Control)

        flpTasks.Controls.Clear()
        For Each TaskName In TaskNames
            Dim PTControl As New PTActivityReporterControl With {
                .TaskName = TaskName
            }
            PTControl.SetColors()
            PTControl.SetInactive()

            PTControls.Add(PTControl)
        Next
        flpTasks.Controls.AddRange(PTControls.ToArray())

        PowerManagementHelper.DisableSystemSleepMode()
        Await Task.Run(Function()
                           Return PreparationTaskHelper.RunTasks(ProgressStartReporter:=Sub(task As String)
                                                                                            ReportTaskStart(task)
                                                                                        End Sub,
                                                                 ProgressFinishedReporter:=Sub(taskStatus As Dictionary(Of String, PreparationTasks.PreparationTask.PreparationTaskStatus), progressPercentage As Double)
                                                                                               ReportTaskSuccess(taskStatus, progressPercentage)
                                                                                           End Sub,
                                                                 ProgressSubProcessReporter:=Sub(Status As String)
                                                                                                 ReportSubProcessStatusUpdate(Status)
                                                                                             End Sub)
                       End Function)
        PowerManagementHelper.EnableSystemSleepMode()
        ButtonPanel.Visible = True
        Next_Button.PerformClick()
    End Sub

    ''' <summary>
    ''' Runs the final Sysprep process with the user-specified Sysprep settings
    ''' </summary>
    ''' <remarks></remarks>
    Sub SysprepComputer()
        Dim powerActionDelayed As Boolean = False

        If Environment.GetCommandLineArgs().Contains("/dt_capture") Then
            ' we are more interested in rebooting the system than shutting it down, in order
            ' to capture the image
            SysprepConfiguration.Shutdown = SysprepConfig.ShutdownMode.Reboot
        End If
        Dim delayedSystemPowerAction As SysprepConfig.ShutdownMode = SysprepConfiguration.Shutdown
        If SysprepConfiguration.CopyProfile Then
            ' We have to let REG do its thing before we apply the correct power action.
            SysprepConfiguration.Shutdown = SysprepConfig.ShutdownMode.Quit
            powerActionDelayed = True
        End If
        Dim CmdLine As String = ParseSysprepSettings()
        If Environment.GetCommandLineArgs().Contains("/test") Then
            MsgBox("Sysprep would be launched with flags " & Quote & CmdLine & Quote, vbOKOnly + vbInformation)
        Else
            Dim runRegProc As New Process() With {
                .StartInfo = New ProcessStartInfo() With {
                    .FileName = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "system32", "reg.exe"),
                    .Arguments = "delete HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /f /v SysprepPrepTool",
                    .CreateNoWindow = True,
                    .WindowStyle = ProcessWindowStyle.Hidden
                }
            }

            runRegProc.Start()
            runRegProc.WaitForExit()

            Dim sysprepProcess As New Process() With {
                .StartInfo = New ProcessStartInfo() With {
                    .FileName = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "system32", "sysprep", "sysprep.exe"),
                    .Arguments = CmdLine
                }
            }

            sysprepProcess.Start()
            sysprepProcess.WaitForExit()

            If Debugger.IsAttached Then MsgBox("Sysprep exited with code " & sysprepProcess.ExitCode, vbOKOnly + vbInformation)
            If SysprepConfiguration.CopyProfile Then
                ' Microsoft recommends that we remove certain keys from the default user's registry to prevent reset issues. We'll
                ' listen to them for once.
                ' https://learn.microsoft.com/en-us/windows-hardware/customize/desktop/unattend/microsoft-windows-shell-setup-copyprofile
                RemoveCopyProfileTemp()
            End If

            If powerActionDelayed AndAlso {SysprepConfig.ShutdownMode.Shutdown, SysprepConfig.ShutdownMode.Reboot}.Contains(delayedSystemPowerAction) Then
                Select Case delayedSystemPowerAction
                    Case SysprepConfig.ShutdownMode.Shutdown
                        Process.Start(Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "system32", "shutdown.exe"), "/s /t 0")
                    Case SysprepConfig.ShutdownMode.Reboot
                        Process.Start(Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "system32", "shutdown.exe"), "/r /t 0")
                End Select
            End If
        End If

        If Environment.GetCommandLineArgs().Contains("/auto") Then Close()
    End Sub

    Private Sub RemoveCopyProfileTemp()
        Dim regProc As New Process() With {
            .StartInfo = New ProcessStartInfo() With {
                .FileName = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "system32", "reg.exe"),
                .CreateNoWindow = True,
                .WindowStyle = ProcessWindowStyle.Hidden
            }
        }

        regProc.StartInfo.Arguments = String.Format("load HKU\DefUser {0}", Quote & String.Format("{0}\Users\Default\NTUSER.DAT", Environment.GetEnvironmentVariable("SYSTEMDRIVE")) & Quote)
        regProc.Start()
        regProc.WaitForExit()
        regProc.StartInfo.Arguments = String.Format("delete {0} /f /v FileAssociationsUpdateVersion", Quote & "HKU\DefUser\Software\Microsoft\Windows\Shell\Associations" & Quote)
        regProc.Start()
        regProc.WaitForExit()
        regProc.StartInfo.Arguments = String.Format("delete {0} /f", Quote & "HKU\DefUser\Software\Microsoft\Windows\Shell\Associations\UrlAssociations" & Quote)
        regProc.Start()
        regProc.WaitForExit()
        regProc.StartInfo.Arguments = String.Format("delete {0} /f", Quote & "HKU\DefUser\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts" & Quote)
        regProc.Start()
        regProc.WaitForExit()
        regProc.StartInfo.Arguments = "unload HKU\DefUser"
        regProc.Start()
        regProc.WaitForExit()
    End Sub

    ''' <summary>
    ''' Parses the current sysprep settings into a command line
    ''' </summary>
    ''' <returns>A set of command line arguments that are passed to sysprep</returns>
    ''' <remarks></remarks>
    Private Function ParseSysprepSettings() As String
        Dim sysprepCommandLine As String = ""
        If SysprepConfiguration.Generalize Then
            sysprepCommandLine &= "/generalize "
        End If
        Select Case SysprepConfiguration.Cleanup
            Case SysprepConfig.CleanupAction.EnterSystemAudit
                sysprepCommandLine &= "/audit "
            Case SysprepConfig.CleanupAction.EnterSystemOobe
                sysprepCommandLine &= "/oobe "
        End Select
        Select Case SysprepConfiguration.Shutdown
            Case SysprepConfig.ShutdownMode.Reboot
                sysprepCommandLine &= "/reboot "
            Case SysprepConfig.ShutdownMode.Shutdown
                sysprepCommandLine &= "/shutdown "
            Case SysprepConfig.ShutdownMode.Quit
                sysprepCommandLine &= "/quit "
        End Select
        ' If we ticked CopyProfile, then we have to use a different answer file, no matter
        ' what the user picked.
        If SysprepConfiguration.CopyProfile Then
            Try
                Dim cpXmlPath As String = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Windows), "sysprep_copyprofile.xml")
                File.WriteAllText(cpXmlPath, My.Resources.UnattendXml_CopyProfile, UTF8)
                sysprepCommandLine &= String.Format("/unattend:{0} ", Quote & cpXmlPath & Quote)
            Catch ex As Exception
                DynaLog.LogMessage("Could not prepare unattended for copyprofile. Error message: " & ex.Message)
                DynaLog.LogMessage("Continuing without answer files...")
                SysprepConfiguration.CopyProfile = False
            End Try
        Else
            If SysprepConfiguration.AnswerFile <> "" AndAlso File.Exists(SysprepConfiguration.AnswerFile) Then
                sysprepCommandLine &= String.Format("/unattend:{0} ", Quote & SysprepConfiguration.AnswerFile & Quote)
            End If
        End If
        If SysprepConfiguration.VMMode Then
            sysprepCommandLine &= "/mode:vm"
        End If

        Return sysprepCommandLine.TrimEnd(" ")
    End Function

    ''' <summary>
    ''' Initializes the default settings
    ''' </summary>
    ''' <remarks></remarks>
    Sub InitializeSettings()
        ' Initialize Sysprep Process Configuration Settings
        AdvSettingsPage_CleanupActionCBox.SelectedIndex = SysprepConfiguration.Cleanup
        AdvSettingsPage_CleanupAction_Generalize.Checked = SysprepConfiguration.Generalize
        AdvSettingsPage_ShutdownOptionsCBox.SelectedIndex = SysprepConfiguration.Shutdown
        AdvSettingsPage_SysprepUnatt_AnswerFileText.Text = SysprepConfiguration.AnswerFile
        AdvSettingsPage_VMMode.Checked = SysprepConfiguration.VMMode
    End Sub

    ''' <summary>
    ''' Handles changes in the sysprep configuration
    ''' </summary>
    ''' <remarks></remarks>
    Sub ChangeSysprepConfiguration()
        SysprepConfiguration.Cleanup = AdvSettingsPage_CleanupActionCBox.SelectedIndex
        SysprepConfiguration.Generalize = AdvSettingsPage_CleanupAction_Generalize.Checked
        SysprepConfiguration.Shutdown = AdvSettingsPage_ShutdownOptionsCBox.SelectedIndex
        SysprepConfiguration.AnswerFile = AdvSettingsPage_SysprepUnatt_AnswerFileText.Text
        SysprepConfiguration.VMMode = AdvSettingsPage_VMMode.Checked
        SysprepConfiguration.CopyProfile = AdvSettingsPage_CopyProfile.Checked

        ' The copyprofile option prevents us from using an answer file. We already use a custom
        ' answer file instead of the user-provided one when ticking the option, but we want to have
        ' a visual indication.
        If SysprepConfiguration.CopyProfile AndAlso SysprepConfiguration.AnswerFile <> "" Then
            MessageBox.Show(GetValueFromLanguageData("MainForm.CopyProfileWarning"), Text, MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
        End If
    End Sub

    Private Sub Back_Button_Click(sender As Object, e As EventArgs) Handles Back_Button.Click
        ChangePage(CurrentWizardPage.WizardPage - 1)
    End Sub

    Private Sub Next_Button_Click(sender As Object, e As EventArgs) Handles Next_Button.Click
        If CurrentWizardPage.WizardPage = WizardPage.Page.FinishPage Then
            Close()
        Else
            ChangePage(CurrentWizardPage.WizardPage + 1)
        End If
    End Sub

    Private Sub Cancel_Button_Click(sender As Object, e As EventArgs) Handles Cancel_Button.Click
        Close()
    End Sub

    Private Sub SysCheckPage_CheckAgainBtn_Click(sender As Object, e As EventArgs) Handles SysCheckPage_CheckAgainBtn.Click
        IsComputerChecked = False
        SysCheckPage_RemoveAppxBtn.Visible = False
        SysCheckPage_DecryptBtn.Visible = False
        CheckComputer()
    End Sub

    Function GetCopyrightTimespan(ByVal start As Integer, ByVal current As Integer) As String
        If current <= start Then
            Return current.ToString()
        Else
            Return start.ToString() & "-" & current.ToString()
        End If
    End Function

    Sub InitDynaLog()
        DynaLog.LogMessage("Sysprep Preparation Tool (" & CodeName & ") - Version " & My.Application.Info.Version.ToString() & ", build timestamp: " & RetrieveLinkerTimestamp().ToString("yyMMdd-HHmm"))
        ' Display copyright/author information for every component
        DynaLog.LogMessage("Components:")
        DynaLog.LogMessage("- Program: " & My.Application.Info.Copyright.Replace("©", "(c)"))
        DynaLog.LogMessage("  Initial expansion and testing also made by Real-MullaC: https://github.com/Real-MullaC")
        DynaLog.LogMessage("- ManagedDism: (c) " & GetCopyrightTimespan(2016, 2016) & " Jeff Kluge")
        DynaLog.LogMessage("- INI File Parser: (c) " & GetCopyrightTimespan(2008, 2008) & " Ricardo Amores Hernández")
        DynaLog.BeginLogging()
    End Sub

    Private Sub MainForm_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        InitDynaLog()
        ChangeLanguage(My.Computer.Info.InstalledUICulture.TwoLetterISOLanguageName)
        ' Because of the DISM API, Windows 7 compatibility is out the window (no pun intended)
        If Environment.OSVersion.Version.Major = 6 And Environment.OSVersion.Version.Minor < 2 Then
            DynaLog.LogMessage("Windows 7 or an earlier version has been detected on this system. Program incompatible -- aborting any future procedures!")
            MsgBox(GetValueFromLanguageData("MainForm.Win7Message"), vbOKOnly + vbCritical, GetValueFromLanguageData("MainForm.WndTitle"))
            Environment.Exit(1)
        End If
        ' I once tested this on a computer which didn't require me to ask for admin privileges. This is a requirement of DISM. Check this
        If Not My.User.IsInRole(ApplicationServices.BuiltInRole.Administrator) Then
            DynaLog.LogMessage("This user is not part of the Administrators group/role -- aborting any future procedures!")
            MsgBox(GetValueFromLanguageData("MainForm.RunAsAdminMessage"), vbOKOnly + vbCritical, GetValueFromLanguageData("MainForm.WndTitle"))
            Environment.Exit(1)
        End If
        ' Prevent tool from running in Safe Mode
        If SystemInformation.BootMode <> BootMode.Normal Then
            DynaLog.LogMessage("This system is in Safe Mode.")
            MsgBox(GetValueFromLanguageData("MainForm.SafeModeNotSupported"), vbOKOnly + vbCritical, GetValueFromLanguageData("MainForm.WndTitle"))
            Environment.Exit(1)
        End If
        OriginalWindowState = WindowState
        OriginalWindowBounds = Bounds
        FormBorderStyle = FormBorderStyle.None
        WindowState = FormWindowState.Maximized
        ChangePage(WizardPage.Page.WelcomePage)
        InitializeSettings()
        AddHandler AdvSettingsPage_CleanupActionCBox.SelectedIndexChanged, AddressOf ChangeSysprepConfiguration
        AddHandler AdvSettingsPage_CleanupAction_Generalize.CheckedChanged, AddressOf ChangeSysprepConfiguration
        AddHandler AdvSettingsPage_ShutdownOptionsCBox.SelectedIndexChanged, AddressOf ChangeSysprepConfiguration
        AddHandler AdvSettingsPage_SysprepUnatt_AnswerFileText.TextChanged, AddressOf ChangeSysprepConfiguration
        AddHandler AdvSettingsPage_VMMode.CheckedChanged, AddressOf ChangeSysprepConfiguration
        AddHandler AdvSettingsPage_CopyProfile.CheckedChanged, AddressOf ChangeSysprepConfiguration
        ChangeTheme()
        FinishPage_CloseBtn.Enabled = Environment.GetCommandLineArgs().Contains("/test")

        SysCheckPage_CheckCH.Width = WindowHelper.ScaleLogical(376)
        SysCheckPage_CompatibleCH.Width = WindowHelper.ScaleLogical(96)
        SysCheckPage_SeverityCH.Width = WindowHelper.ScaleLogical(128)

        If Environment.GetCommandLineArgs().Contains("/copyprofile") Then
            AdvSettingsPage_CopyProfile.Checked = True
        End If

        If Environment.GetCommandLineArgs().Contains("/skipwelcome") Then
            Next_Button.PerformClick()
        End If

        If Environment.GetCommandLineArgs().Contains("/auto") Then
            RunAutoMode()
        End If
    End Sub

    Private Sub SysCheckPage_ChecksLv_SelectedIndexChanged(sender As Object, e As EventArgs) Handles SysCheckPage_ChecksLv.SelectedIndexChanged
        SysCheckPage_CheckDetailsTLP.Visible = (SysCheckPage_ChecksLv.SelectedItems.Count = 1)
        If SysCheckPage_ChecksLv.SelectedItems.Count = 1 Then
            Dim focusedIdx As Integer = SysCheckPage_ChecksLv.FocusedItem.Index

            SysCheckPage_CheckDetails_Title.Text = PerformedChecks(focusedIdx).StatusMessage.StatusTitle
            SysCheckPage_CheckDetails_DescriptionValue.Text = PerformedChecks(focusedIdx).StatusMessage.StatusDescription
            SysCheckPage_CheckDetails_ResolutionValue.Text = PerformedChecks(focusedIdx).StatusMessage.StatusPossibleResolution

            ' Present cool buttons when we select the appropriate option
            Dim performedCheck As CompatibilityCheckerProviderStatus = PerformedChecks.ElementAtOrDefault(focusedIdx)
            If performedCheck Is Nothing Then Exit Sub
            SysCheckPage_RemoveAppxBtn.Visible = performedCheck.StatusMessage.StatusTitle = GetValueFromLanguageData("ThirdPartyAppxCCP.CCPTitle") AndAlso File.Exists(Path.Combine(Application.StartupPath, "Tools", "RemoveOnlineAppxPackage.ps1"))
            SysCheckPage_DecryptBtn.Visible = performedCheck.StatusMessage.StatusTitle = GetValueFromLanguageData("BitLockerCCP.CCPTitle") AndAlso Not performedCheck.Compatible
        End If
    End Sub

    Private Sub AdvSettingsPage_ConfigSysprepSettings_CheckedChanged(sender As Object, e As EventArgs) Handles AdvSettingsPage_ConfigSysprepSettings.CheckedChanged
        AdvSettingsPage_SysprepConfigPanel.Enabled = AdvSettingsPage_ConfigSysprepSettings.Checked
    End Sub

    Private Sub AdvSettingsPage_VMModeExplanationLink_LinkClicked(sender As Object, e As LinkLabelLinkClickedEventArgs) Handles AdvSettingsPage_VMModeExplanationLink.LinkClicked
        Process.Start("https://learn.microsoft.com/en-us/windows-hardware/manufacture/desktop/sysprep-command-line-options?view=windows-11#modevm")
    End Sub

    Private Sub AdvSettingsPage_SysprepUnatt_Btn_Click(sender As Object, e As EventArgs) Handles AdvSettingsPage_SysprepUnatt_Btn.Click
        AdvSettingsPage_SysprepUnatt_OFD.ShowDialog()
    End Sub

    Private Sub AdvSettingsPage_SysprepUnatt_OFD_FileOk(sender As Object, e As System.ComponentModel.CancelEventArgs) Handles AdvSettingsPage_SysprepUnatt_OFD.FileOk
        AdvSettingsPage_SysprepUnatt_AnswerFileText.Text = AdvSettingsPage_SysprepUnatt_OFD.FileName
    End Sub

    Private Sub FinishPage_CloseBtn_Click(sender As Object, e As EventArgs) Handles FinishPage_CloseBtn.Click
        Close()
    End Sub

    Private Sub FinishPage_ResysprepBtn_Click(sender As Object, e As EventArgs) Handles FinishPage_ResysprepBtn.Click
        SysprepComputer()
    End Sub

    Private Sub FinishPage_RestartBtn_Click(sender As Object, e As EventArgs) Handles FinishPage_RestartBtn.Click
        Process.Start("shutdown", "-r -t 00")
    End Sub

    Private Sub MainForm_KeyDown(sender As Object, e As KeyEventArgs) Handles MyBase.KeyDown
        If e.KeyCode = Keys.F11 Then
            ToggleFullScreenMode()
        End If
    End Sub

    Sub ToggleFullScreenMode()
        If FormBorderStyle = Windows.Forms.FormBorderStyle.None Then
            DynaLog.LogMessage("Exiting full-screen mode...")
            FormBorderStyle = Windows.Forms.FormBorderStyle.FixedSingle
            Bounds = OriginalWindowBounds
            WindowState = OriginalWindowState
        Else
            DynaLog.LogMessage("Entering full-screen mode...")
            FormBorderStyle = Windows.Forms.FormBorderStyle.None
            OriginalWindowState = WindowState
            WindowState = FormWindowState.Normal
            OriginalWindowBounds = Bounds
            Bounds = Screen.FromControl(Me).Bounds
        End If
    End Sub

    Private Sub MainForm_FormClosing(sender As Object, e As FormClosingEventArgs) Handles Me.FormClosing
        If SettingPreparationPanel.Visible Then
            e.Cancel = True
            Exit Sub
        End If

        DynaLog.LogMessage("We Are Done")
        DynaLog.EndLogging()
    End Sub

    Private Sub AboutBtn_Click(sender As Object, e As EventArgs) Handles AboutBtn.Click
        MsgBox(String.Format(GetValueFromLanguageData("MainForm.AboutMessage"),
                             My.Application.Info.Version.ToString(),
                             RetrieveLinkerTimestamp().ToString("yyMMdd-HHmm"),
                             My.Application.Info.Copyright.Replace("©", "(c)"),
                             GetCopyrightTimespan(2016, 2016) & " Jeff Kluge",
                             GetCopyrightTimespan(2008, 2008) & " Ricardo Amores Hernández"), vbOKOnly + vbInformation, GetValueFromLanguageData("Common.Common_About"))
    End Sub

    Private Sub SysCheckPage_RemoveAppxBtn_Click(sender As Object, e As EventArgs) Handles SysCheckPage_RemoveAppxBtn.Click
        OnlineAppxRemovalDialog.ShowDialog(Me)
    End Sub

    Private Sub SysCheckPage_DecryptBtn_Click(sender As Object, e As EventArgs) Handles SysCheckPage_DecryptBtn.Click
        SysvolBDEDecryptDialog.ShowDialog(Me)
        IsComputerChecked = False
        CheckComputer()
    End Sub
End Class