build_rules.wls

#!/usr/bin/env wolframscript

root = DirectoryName[$InputFileName];
PacletDirectoryLoad[root];
Needs["Lightmarey`FormulaTransformEngine`"];

sourceFiles = Sort@FileNames["*.ftr.md", FileNameJoin[{root, "Registry", "Sources"}]];
irFiles = Sort@FileNames[{"*.family.json", "*.monotonicity.json"}, FileNameJoin[{root, "Registry", "IR"}]];
sourceCompiled = CompileFormulaTransformSource /@ sourceFiles;
irData = Import[#, "RawJSON"] & /@ irFiles;
irCompiled = Map[Switch[Lookup[#, "Kind", None],
    "TransformFamily", CompileFormulaTransformFamily[#],
    "MonotonicityDescriptor", CompileFormulaTransformMonotonicityDescriptor[#],
    _, Failure["InvalidRuleIR", <||>]] &, irData];

failures = Select[Join[sourceCompiled, irCompiled], FailureQ];
If[failures =!= {},
  Scan[
    If[KeyExistsQ[Lightmarey`FormulaTransformEngine`Private`FTFailureData[#], "File"],
      Print[Lightmarey`FormulaTransformEngine`Private`FTFormatRuleSourceDiagnostic[#]],
      Print[InputForm[#]]
    ] &,
    failures
  ];
  Exit[1]
];

ruleDigestView[rule_] := KeyTake[rule, {
  "RuleId", "SemanticDigest", "ExecutionDigest", "RecordDigest", "SourceDigest",
  "Tags", "Meta"
}];

digestView[item_] := If[Lookup[item, "Kind"] === "TransformFamily",
  <|"Kind" -> "TransformFamily", "Name" -> item["Name"],
    "Parameters" -> item["Parameters"], "GeneratedParameters" -> item["GeneratedParameters"],
    "Tags" -> item["Tags"], "Meta" -> item["Meta"], "SourceDigest" -> item["SourceDigest"],
    "Variants" -> SortBy[ruleDigestView /@ item["Variants"], Lookup[#, "RuleId"] &],
    "Heuristics" -> SortBy[ruleDigestView /@ item["Heuristics"], Lookup[#, "RuleId"] &]|>,
  KeyTake[item, {"Kind", "Name", "SemanticDigest", "RecordDigest", "SourceDigest", "Meta"}]
];

sourceView = SortBy[digestView /@ sourceCompiled, Lookup[#, "Name"] &];
irView = SortBy[digestView /@ irCompiled, Lookup[#, "Name"] &];

If[sourceView =!= irView,
  Print["Rule source and JSON IR are out of sync."];
  Print[InputForm[<|"Source" -> sourceView, "IR" -> irView|>]];
  Exit[1]
];

Print["Rule source and JSON IR are synchronized: ", Length[sourceFiles], " compiled items."];
Exit[0];